Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

import "./Exponential-0.8.sol";
import "./Tokenomics/rewards/CTokenRewards.sol";

interface Comptroller {
    function isComptroller() external view returns (bool);
    function getAllMarkets() external view returns (address[] memory);
    function oracle() external view returns (PriceOracle);
    function markets(address) external view returns (bool, uint);
    function supplyRewardSpeeds(uint8, address) external view returns (uint);
    function borrowRewardSpeeds(uint8, address) external view returns (uint);
    function borrowCaps(address) external view returns (uint);
    function checkMembership(address account, CToken cToken) external view returns (bool);
    function rewardAccrued(uint8, address) external view returns (uint);
    function rewardBorrowState(uint8, address) external view returns (uint224, uint32);
    function rewardSupplyState(uint8, address) external view returns (uint224, uint32);
    function rewardBorrowerIndex(uint8, address, address) external view returns (uint);
    function rewardSupplierIndex(uint8, address, address) external view returns (uint);
    function initialIndexConstant() external view returns (uint224);
    function mintGuardianPaused(address market) external view returns (bool);
    function borrowGuardianPaused(address market) external view returns (bool);
    function getAllRewardTokens() external view returns (address[] memory rewardTokens);
}

interface CToken {
    function borrowRatePerTimestamp() external view returns (uint);
    function supplyRatePerTimestamp() external view returns (uint);
    function exchangeRateStored() external view returns (uint);
    function reserveFactorMantissa() external view returns (uint);
    function totalSupply() external view returns (uint);
    function totalBorrows() external view returns (uint);
    function underlying() external view returns (address);
    function balanceOf(address) external view returns (uint);
    function allowance(address, address) external view returns (uint);
    function borrowBalanceStored(address) external view returns (uint);
    function decimals() external view returns (uint);
    function totalReserves() external view returns (uint);
    function getCash() external view returns (uint);
    function borrowIndex() external view returns (uint);
}

interface PriceOracle {
    function getUnderlyingPrice(CToken cToken) external view returns (uint);
}

interface PriceOracleV2 {
    function isPriceOracle() external pure returns (bool);
    function getUnderlyingPrice(CToken cToken) external view returns (uint);
    function getPrice(address token) external view returns (uint);
    function getEtherPrice() external view returns (uint);
}

interface UnderlyingToken {
    function decimals() external view returns (uint);
    function balanceOf(address) external view returns (uint);
    function allowance(address, address) external view returns (uint);
}

interface PangolinLPToken {
    function balanceOf(address) external view returns (uint);
    function allowance(address, address) external view returns (uint);
    function totalSupply() external view returns (uint);
    function getReserves() external view returns (uint112, uint112, uint32);
    function kLast() external view returns (uint);
}

interface PglStakingContract {
    function pglTokenAddress() external view returns (address);
    function totalSupplies() external view returns (uint);
    function rewardSpeeds(uint) external view returns (uint);
    function supplyAmount(address) external view returns (uint);

    function rewardIndex(uint) external view returns (uint);
    function supplierRewardIndex(address, uint) external view returns (uint);
    function accruedReward(address, uint) external view returns (uint);
}

interface GenesisPoolStakingContract {
    function genesisPoolCTokenAddress() external view returns (address);
    function totalSupplies() external view returns (uint);
    function rewardSpeed() external view returns (uint);
    function supplyAmount(address) external view returns (uint);

    function accrualBlockTimestamp() external view returns (uint);
    function rewardIndex() external view returns (uint);
    function supplierRewardIndex(address) external view returns (uint);
    function accruedReward(address) external view returns (uint);
}

struct ProtocolTokens {
    address esProtocolAddress;
    address protocolAddress;
}

contract Lens is ExponentialNoError {
    Comptroller immutable public comptroller;
    PglStakingContract immutable public pglStakingContract;
    GenesisPoolStakingContract[] public genesisPoolStakingContracts;
    CTokenRewards[] public cTokenRewardsContracts;
    address immutable public esProtocolAddress;
    address immutable public protocolAddress;
    address immutable public pangolinRouter;
    PriceOracleV2 immutable public priceOracleV2;

    constructor(address comptrollerAddress,
                address pglStakingContractAddress,
                address pangolinRouterAddress,
                GenesisPoolStakingContract[] memory genesisPoolStakingContracts_,
                CTokenRewards[] memory cTokenRewardsContracts_,
                ProtocolTokens memory protocolTokens,
                PriceOracleV2 priceOracleV2_) {
        comptroller = Comptroller(comptrollerAddress);
        pglStakingContract = PglStakingContract(pglStakingContractAddress);
        genesisPoolStakingContracts = genesisPoolStakingContracts_;
        cTokenRewardsContracts = cTokenRewardsContracts_;
        esProtocolAddress = protocolTokens.esProtocolAddress;
        protocolAddress = protocolTokens.protocolAddress;
        
        require(priceOracleV2_.isPriceOracle(), 'Invalid priceOracle');
        priceOracleV2 = priceOracleV2_;

        require(comptroller.isComptroller(), 'Invalid comptroller address');
        require((pglStakingContractAddress == address(0) && pangolinRouterAddress == address(0)) 
            || pglStakingContract.pglTokenAddress() != address(0), 'Invalid pglStakingContract');

        pangolinRouter = pangolinRouterAddress;
    }

    struct MarketMetadata {
        /// @dev Market (CToken) address
        address market;

        /// @dev Interest rate model's supply rate
        uint supplyRate;

        /// @dev Interest rate model's borrow rate
        uint borrowRate;

        /// @dev Token price (decimal count 36 - underlying decimals)
        uint price;

        /// @dev CToken to underlying token exchange rate (18 - CToken decimals + underlying decimals)
        uint exchangeRate;

        /// @dev Reserve factor percentage (18 decimals)
        uint reserveFactor;

        /// @dev Maximum total borrowable amount for the market, denominated in the underlying asset
        uint borrowCap;

        /// @dev Total supply, denominated in CTokens
        uint totalSupply;

        /// @dev Total supply, denominated in the underlying token
        uint totalUnderlyingSupply;

        /// @dev Total borrows, denominated in the underlying token
        uint totalBorrows;

        /// @dev Collateral factor (18 decimals)
        uint collateralFactor;

        /// @dev Underlying token address
        address underlyingToken;

        /// @dev Underlying token decimal count
        uint underlyingTokenDecimals;

        /// @dev Market CToken decimal count
        uint cTokenDecimals;

        /// @dev Amount of rewards rewarded to suppliers every second
        uint[] supplyRewardSpeeds;
        
        /// @dev Amount of rewards rewarded to borrowers every second
        uint[] borrowRewardSpeeds;

        /// @dev Total amount of reserves of the underlying held in this market
        uint totalReserves;

        /// @dev Cash balance of this cToken in the underlying token (underlying token's decimals)
        uint cash;

        /// @dev Indicates if adding supply is paused
        bool mintPaused;

        /// @dev Indicates if borrowing is paused
        bool borrowPaused;
    }

    struct AccountSnapshot {
        AccountMarketSnapshot[] accountMarketSnapshots;
        AccountRewards rewards;
    }

    struct AccountRewards {
        /// @dev Rewards that can be claimed through the comptroller contract
        AccountComptrollerRewards comptroller;

        /// @dev Rewards that can be claimed through the contract for CTokenRewards
        AccountCTokenRewards[] cTokenRewards;

        /// @dev Rewards that can be claimed through the genesis pools contracts
        AccountGenesisPoolRewards[] genesisPools;
    }

    struct AccountMarketSnapshot {
        /// @dev Market address
        address market;

        /// @dev Account's wallet balance for the underlying token
        uint balance;

        /// @dev The allowed maximum expenditure of the underlying token by the market contract
        uint allowance;

        /// @dev Account's supply balance, denominated in the underlying token
        uint supplyBalance;

        /// @dev Account's borrow balance, denominated in the underlying token
        uint borrowBalance;

        /// @dev Indicates if a market is avaiable as collateral on the account
        bool collateralEnabled;
    }

    struct ComptrollerReward{        
        uint8 rewardType;
        uint unclaimedAmount;
    }

    struct AccountComptrollerRewards {
        ComptrollerReward[] unclaimedRewards;

        /// @dev List of all markets in which the user has unclaimed rewards
        address[] markets;
    }

    struct AccountRewardErc20Info {
        /// @dev Amount of unclaimed token rewards (18 decimals)
        uint amount;

        /// @dev Address of the associated reward token
        address rewardTokenAddress;
    }

    struct AccountCTokenRewards {
        /// @dev The contract where the rewards can be claimed
        CTokenRewards rewardContract;

        /// @dev Amount of unclaimed native token rewards (18 decimals)
        uint unclaimedNativeToken;

        /// @dev Info about unclaimed ERC20 token rewards
        AccountRewardErc20Info[] unclaimedErc20;
    }

    struct AccountGenesisPoolRewards {
        /// @dev Address of the genesis pool where the rewards can be claimed
        GenesisPoolStakingContract poolAddress;

        /// @dev The address of the cToken deposited to the genesis pool
        address cTokenAddress;

        /// @dev Amount of unclaimed esProtocol token rewards (18 decimals)
        uint unclaimedEsProtocolToken;
    }

    struct AccountPglSnapshot {
        /// @dev The PGL balance of the user's wallet (PGL token`s decimals)
        uint balance;

        /// @dev The amount of PGL tokens the user has deposited (PGL token`s decimals)
        uint deposited;

        /// @dev Unclaimed protocol token rewards (18 decimals)
        uint unclaimedProtocolToken;

        /// @dev The allowed maximum expenditure of the user's PGL tokens by the staking contract (PGL token`s decimals)
        uint pglStakingContractAllowance;

        /// @dev The allowed maximum expenditure of the user's protocol tokens (actual protocol tokens, not cTokens) by the pangolin router (18 decimals)
        uint pangolinRouterProtocolTokenAllowance;
    }

    struct AccountGenesisPoolSnapshot {
        /// @dev Address of the genesis pool
        GenesisPoolStakingContract poolAddress;

        /// @dev The address of the cToken deposited to the genesis pool
        address cTokenAddress;

        /// @dev Amount of unclaimed esProtocol token rewards (18 decimals)
        uint unclaimedEsProtocolToken;

        /// @dev The cToken balance of the user's wallet (CToken`s decimals)
        uint balance;

        /// @dev The amount of GenesisPool tokens the user has deposited (GenesisPool token`s decimals)
        uint deposited;

        /// @dev The allowed maximum expenditure of the user's GenesisPool tokens by the staking contract (GenesisPool token`s decimals)
        uint stakingContractAllowance;
    }

    struct MarketPglSnapshot {
        /// @dev Total PGL token amount deposited into the staking contract (PGL token's decimals)
        uint totalDepositedPglTokenAmount;

        /// @dev total supply of PGL tokens (18 decimals)
        uint pglTokenTotalSupply;

        /// @dev amount of protocol tokens in the pool (18 decimals)
        uint pglProtocolTokenReserves;

        /// @dev amount of native tokens in the pool (18 decimals)
        uint pglNativeTokenReserves;

        /// @dev reserve0 * reserve1
        uint kLast;

        /// @dev APR (18 decimals, 1e18 means 100%)
        uint apr;
    }

    struct MarketGenesisPoolSnapshot {
        /// @dev Address of the genesis pool
        GenesisPoolStakingContract poolAddress;

        /// @dev The address of the cToken deposited to the genesis pool
        address cTokenAddress;

        /// @dev Total cToken amount deposited into the staking contract (CToken's decimals)
        uint totalDepositedCTokenAmount;

        /// @dev Total supply of cToken (CToken's decimals)
        uint cTokenTotalSupply;

        /// @dev Exchange rate from the cToken to the underlying token (18 decimals)
        uint cTokenExchangeRate;

        /// @dev price of underlying token of the deposited cToken (18 decimals)
        uint underlyingTokenPrice;

        /// @dev Reward accrual speeds as tokens per second (ESProtocol's decimals)
        uint esProtocolRewardSpeed;

        /// @dev APR (18 decimals, 1e18 means 100%)
        uint apr;
    }

    /**
     * @notice Get prices for the base tokens used by the protocol (the ProtocolToken and the network native token)
     * @return protocolTokenPrice Price of the protocolToken (18 decimals)
     * @return nativeTokenPrice Price of the native token (18 decimals)
     */
    function getPrices() external view returns (uint protocolTokenPrice, uint nativeTokenPrice) {
        nativeTokenPrice = priceOracleV2.getEtherPrice();
        protocolTokenPrice = priceOracleV2.getPrice(protocolAddress);
    }

    /**
     * @notice Get metadata for a specific market
     * @param  market The ctoken address which metadata will be fetched for
     * @return Market metadata
     */
    function getMarketMetadata(CToken market) external view returns (MarketMetadata memory) {
        return _getMarketMetadata(market);
    }

    /**
     * @notice Get metadata for all markets
     * @return Market metadata for all markets
     */
    function getMarketMetadataForAllMarkets() external view returns (MarketMetadata[] memory) {
        address[] memory allMarkets = comptroller.getAllMarkets();
        uint marketCount = allMarkets.length;

        MarketMetadata[] memory metadata = new MarketMetadata[](marketCount);

        for (uint i; i < marketCount;) {
            metadata[i] = _getMarketMetadata(CToken(allMarkets[i]));
            unchecked { ++i; }
        }

        return metadata;
    }

    /**
     * @notice Get account-specific data for supply and borrow positions
     * @param  account Account for the snapshot
     * @return Account snapshot array
     */
    function getAccountSnapshot(address account) external view returns (AccountSnapshot memory) {
        return _getAccountSnapshot(account);
    }

    /**
     * @notice Calculate an account snapshot for a specific market
     * @param  account The account which the snapshot will belong to
     * @param  market The specific market which a snapshot will be calculated for the given account
     * @return Account snapshot
     */
    function getAccountMarketSnapshot(address account, CToken market) external view returns (AccountMarketSnapshot memory) {
        return _getAccountMarketSnapshot(account, market);
    }

    /**
     * @notice Calculate account-specific GenesisPool staking snapshots for each GenesisPool
     * @param  account The account which the snapshot will belong to
     * @return snapshots Account snapshot array for GenesisPool data
     */
    function getAccountGenesisPoolSnapshot(address account) external view returns (AccountGenesisPoolSnapshot[] memory snapshots) {
        uint genesisPoolCount = genesisPoolStakingContracts.length;
        snapshots = new AccountGenesisPoolSnapshot[](genesisPoolCount);

        for (uint i; i < genesisPoolCount;) {
            snapshots[i] = _getAccountGenesisPoolSnapshot(account, genesisPoolStakingContracts[i]);

            unchecked {
                ++i;
            }
        }
    }

    /**
     * @notice Calculate the GenesisPool market snapshots
     * @return Market snapshot for GenesisPool data
     */
    function getMarketGenesisPoolSnapshots() external view returns (MarketGenesisPoolSnapshot[] memory) {
        uint genesisPoolCount = genesisPoolStakingContracts.length;
        MarketGenesisPoolSnapshot[] memory snapshots = new MarketGenesisPoolSnapshot[](genesisPoolCount);

        for (uint i; i < genesisPoolCount;) {
            snapshots[i] = _getMarketGenesisPoolSnapshot(genesisPoolStakingContracts[i]);

            unchecked {
                ++i;
            }
        }

        return snapshots;
    }

    function _getMarketMetadata(CToken market) internal view returns (MarketMetadata memory) {
        address marketAddress = address(market);
        (, uint collateralFactor) = comptroller.markets(marketAddress);

        address underlyingToken;
        uint underlyingTokenDecimals;
       
        underlyingToken = market.underlying();
        underlyingTokenDecimals = UnderlyingToken(underlyingToken).decimals();

        uint totalSupply = market.totalSupply();
        uint totalUnderlyingTokenSupply = _cTokenBalanceToUnderlying(totalSupply, market);
        
        uint rewards = comptroller.getAllRewardTokens().length;
        
        uint[] memory supplyRewardSpeeds = new uint[](rewards);
        uint[] memory borrowRewardSpeeds = new uint[](rewards);
        
        for(uint8 r; r < rewards; r++){        
            supplyRewardSpeeds[r] = comptroller.supplyRewardSpeeds(r, marketAddress);
            borrowRewardSpeeds[r] = comptroller.borrowRewardSpeeds(r, marketAddress);
        }
        

        MarketMetadata memory metadata = MarketMetadata(
            marketAddress,
            market.supplyRatePerTimestamp(),
            market.borrowRatePerTimestamp(),
            comptroller.oracle().getUnderlyingPrice(market),
            market.exchangeRateStored(),
            market.reserveFactorMantissa(),
            comptroller.borrowCaps(marketAddress),
            totalSupply,
            totalUnderlyingTokenSupply,
            market.totalBorrows(),
            collateralFactor,
            underlyingToken,
            underlyingTokenDecimals,
            market.decimals(),
            supplyRewardSpeeds,
            borrowRewardSpeeds,            
            market.totalReserves(),
            market.getCash(),
            comptroller.mintGuardianPaused(marketAddress),
            comptroller.borrowGuardianPaused(marketAddress)
        );

        return metadata;
    }

    function _getAccountSnapshot(address account) internal view returns (AccountSnapshot memory) {
        address[] memory allMarkets = comptroller.getAllMarkets();
        uint marketCount = allMarkets.length;

        AccountMarketSnapshot[] memory snapshots = new AccountMarketSnapshot[](marketCount);

        for (uint i; i < marketCount;) {
            snapshots[i] = _getAccountMarketSnapshot(account, CToken(allMarkets[i]));
            unchecked { ++i; }
        }

        AccountComptrollerRewards memory comprollerRewards = _getAccountComptrollerRewards(account);
        AccountCTokenRewards[] memory cTokenRewards = _getAccountCTokenRewards(account);
        AccountGenesisPoolRewards[] memory genesisPoolRewards = _getAccountGenesisPoolsRewards(account);

        return AccountSnapshot(
            snapshots,
            AccountRewards(
                comprollerRewards,
                cTokenRewards,
                genesisPoolRewards
            )
        );
    }

    function _getAccountComptrollerRewards(address account) internal view returns (AccountComptrollerRewards memory) {
        (
            ComptrollerReward[] memory unclaimedRewards,
            address[] memory marketsWithClaimableRewards
        ) = getComptrollerClaimableRewards(account);

        return AccountComptrollerRewards(unclaimedRewards, marketsWithClaimableRewards);
    }

    function _getAccountCTokenRewards(address account) internal view returns (AccountCTokenRewards[] memory cTokenRewards) {
        unchecked {
            uint numCTokenContracts = cTokenRewardsContracts.length;
            cTokenRewards = new AccountCTokenRewards[](numCTokenContracts);

            for (uint i; i < numCTokenContracts;++i) {
                cTokenRewards[i] = getCTokenClaimableRewards(account, cTokenRewardsContracts[i]);
            }
        }
    }

    function _getAccountGenesisPoolsRewards(address account) internal view returns (AccountGenesisPoolRewards[] memory genesisPoolsRewards) {
        unchecked {
            uint numGenesisPoolsContracts = genesisPoolStakingContracts.length;
            genesisPoolsRewards = new AccountGenesisPoolRewards[](numGenesisPoolsContracts);

            for (uint i; i < numGenesisPoolsContracts;++i) {
                genesisPoolsRewards[i] = getGenesisPoolsClaimableRewards(account, genesisPoolStakingContracts[i]);
            }
        }
    }

    function _getAccountMarketSnapshot(address account, CToken market) internal view returns (AccountMarketSnapshot memory) {
        uint balance;
        uint allowance;

        UnderlyingToken underlyingToken = UnderlyingToken(market.underlying());

        balance = underlyingToken.balanceOf(account);
        allowance = underlyingToken.allowance(account, address(market));
    
        uint cTokenBalance = market.balanceOf(account);
        uint supplyBalance = _cTokenBalanceToUnderlying(cTokenBalance, market);
        bool collateralEnabled = comptroller.checkMembership(account, market);

        return AccountMarketSnapshot(
            address(market),
            balance,
            allowance,
            supplyBalance,
            market.borrowBalanceStored(account),
            collateralEnabled
        );
    }

    function _getAccountGenesisPoolSnapshot(address account, GenesisPoolStakingContract genesisPoolContract) internal view returns (AccountGenesisPoolSnapshot memory) {
        CToken cToken = CToken(genesisPoolContract.genesisPoolCTokenAddress());

        uint balance = cToken.balanceOf(account);
        uint deposited = genesisPoolContract.supplyAmount(account);

        uint unclaimedProtocolToken = updateAndDistributeGenesisPoolRewards(account, genesisPoolContract);

        uint genesisPoolContractAllowance = cToken.allowance(account, address(genesisPoolContract));

        return AccountGenesisPoolSnapshot(
            genesisPoolContract,
            address(cToken),
            unclaimedProtocolToken,
            balance,
            deposited,
            genesisPoolContractAllowance
        );
    }

    function _getMarketGenesisPoolSnapshot(GenesisPoolStakingContract genesisPoolStakingContract) internal view returns (MarketGenesisPoolSnapshot memory) {
        CToken cToken = CToken(genesisPoolStakingContract.genesisPoolCTokenAddress());
        PriceOracle oracle = comptroller.oracle();

        uint totalDepositedCTokenAmount = genesisPoolStakingContract.totalSupplies();
        uint cTokenTotalSupply = cToken.totalSupply();
        uint cTokenExchangeRate = cToken.exchangeRateStored();
        uint underlyingTokenPrice = oracle.getUnderlyingPrice(cToken);

        uint esProtocolRewardSpeed = genesisPoolStakingContract.rewardSpeed();

        uint apr = _calculateAPR(
            esProtocolRewardSpeed,
            priceOracleV2.getPrice(protocolAddress),
            _cTokenBalanceToUnderlying(totalDepositedCTokenAmount, cToken),
            underlyingTokenPrice
        );

        return MarketGenesisPoolSnapshot(
            genesisPoolStakingContract,
            address(cToken),
            totalDepositedCTokenAmount,
            cTokenTotalSupply,
            cTokenExchangeRate,
            underlyingTokenPrice,
            esProtocolRewardSpeed,
            apr
        );
    }

    function _calculatePglAPR(
        uint protocolTokenRewardSpeed,
        uint protocolTokenReserves,
        uint nativeTokenReserves,
        uint protocolTokenPrice,
        uint nativeTokenPrice,
        uint pglTotalSupply,
        uint totalDepositedPGLTokenAmount
    ) internal pure returns (uint usdPerStakedPglValue) {
        uint protocolTokenReservesValue = (protocolTokenReserves * protocolTokenPrice);
        uint nativeTokenReserveValue = (nativeTokenReserves * nativeTokenPrice);

        uint pglPrice = (protocolTokenReservesValue + nativeTokenReserveValue) / pglTotalSupply;

        usdPerStakedPglValue = _calculateAPR(
            protocolTokenRewardSpeed,
            protocolTokenPrice,
            totalDepositedPGLTokenAmount,
            pglPrice
        );
    }

    function _calculateAPR(
        uint protocolTokenRewardSpeed,
        uint protocolTokenPrice,
        uint totalDepositedTokenAmount,
        uint depositedTokenPrice
    ) internal pure returns (uint) {
        uint totalStakedValue = totalDepositedTokenAmount * depositedTokenPrice / 1e18;
        
        if(totalStakedValue == 0){
            return 0;
        }

        uint protocolTokenUsdValuePerYear = protocolTokenRewardSpeed * (60 * 60 * 24 * 365) * protocolTokenPrice;

        return protocolTokenUsdValuePerYear / totalStakedValue;
    }

    function getComptrollerClaimableRewards(address user) internal view returns (ComptrollerReward[] memory, address[] memory) {
        uint8 rewards = uint8(comptroller.getAllRewardTokens().length);        
        uint marketsCount = comptroller.getAllMarkets().length;        
        ComptrollerReward[] memory unclaimedRewards = new ComptrollerReward[](rewards);
        address[] memory rewardMarkets = new address[](marketsCount);
        uint uniqueRewardMarketCount;
        
        for(uint8 r; r < rewards; r++){
            (uint claimableAmount, address[] memory markets) = getComptrollerClaimableReward(user, r);

            unclaimedRewards[r] = ComptrollerReward(r, claimableAmount);

            for (uint i; i < markets.length;++i) {
                bool duplicate = false;

                for (uint j; j < uniqueRewardMarketCount;++j) {
                    if(rewardMarkets[j] == markets[i]) {
                        duplicate = true;
                        break;
                    }
                }

                if (!duplicate) {
                    rewardMarkets[uniqueRewardMarketCount] = markets[i];
                    ++uniqueRewardMarketCount;
                }
            }
        }

        address[] memory marketsWithClaimableRewards = new address[](uniqueRewardMarketCount);

        for (uint i; i < uniqueRewardMarketCount; ++i) {
            marketsWithClaimableRewards[i] = rewardMarkets[i];
        }

        return (unclaimedRewards, marketsWithClaimableRewards);        
    }
    
    function getComptrollerClaimableReward(address user, uint8 rewardType) public view returns (uint, address[] memory) {
        address[] memory markets = comptroller.getAllMarkets();
        uint numMarkets = markets.length;

        uint accrued = comptroller.rewardAccrued(rewardType, user);

        uint totalMarketAccrued;

        address[] memory rawMarketsWithRewards = new address[](numMarkets);
        uint numMarketsWithRewards;

        for (uint i; i < numMarkets;) {
            CToken market = CToken(markets[i]);

            totalMarketAccrued = updateAndDistributeSupplierReward(rewardType, market, user);
            totalMarketAccrued += updateAndDistributeBorrowerReward(rewardType, market, user);

            accrued += totalMarketAccrued;

            if (totalMarketAccrued > 0) {
                rawMarketsWithRewards[numMarketsWithRewards++] = address(market);
            }

            unchecked { ++i; }
        }

        address[] memory marketsWithRewards = new address[](numMarketsWithRewards);

        for (uint i; i < numMarketsWithRewards;) {
            marketsWithRewards[i] = rawMarketsWithRewards[i];
            unchecked { ++i; }
        }

        return (accrued, marketsWithRewards);
    }

    function getCTokenClaimableRewards(address account, CTokenRewards cTokenRewards) internal view returns (AccountCTokenRewards memory) {
        uint rewardTokensLength = cTokenRewards.rewardTokensLength();

        uint unclaimedNative = cTokenRewards.userPendingEther(account);
        AccountRewardErc20Info[] memory unclaimedErc20 = new AccountRewardErc20Info[](rewardTokensLength);

        for (uint i; i < rewardTokensLength;) {
            address rewardTokenAddress = cTokenRewards.rewardTokenAt(i);
            uint unclaimedAmount = cTokenRewards.userPendingRewards(IERC20(rewardTokenAddress), account);
            unclaimedErc20[i] = AccountRewardErc20Info(unclaimedAmount, rewardTokenAddress);

            unchecked {
                ++i;
            }
        }

        return AccountCTokenRewards(cTokenRewards, unclaimedNative, unclaimedErc20);
    }

    function getGenesisPoolsClaimableRewards(address account, GenesisPoolStakingContract genesisPoolContract) internal view returns (AccountGenesisPoolRewards memory) {
        uint unclaimedRewards = updateAndDistributeGenesisPoolRewards(account, genesisPoolContract);
        return AccountGenesisPoolRewards(genesisPoolContract, genesisPoolContract.genesisPoolCTokenAddress(), unclaimedRewards);
    }

    function updateAndDistributeGenesisPoolRewards(address recipient, GenesisPoolStakingContract genesisPool) internal view returns (uint unclaimedRewards) {
        uint rewardIndex = accrueRewardGenesisPool(genesisPool);

        uint rewardIndexDelta = rewardIndex - genesisPool.supplierRewardIndex(recipient);
        uint accruedAmount = rewardIndexDelta * genesisPool.supplyAmount(recipient) / 1e36;
        unclaimedRewards = genesisPool.accruedReward(recipient) + accruedAmount;
    }

    function accrueRewardGenesisPool(GenesisPoolStakingContract genesisPoolContract) internal view returns (uint) {
        uint blockTimestampDelta = block.timestamp - genesisPoolContract.accrualBlockTimestamp();
        uint totalSupplies = genesisPoolContract.totalSupplies();
        uint rewardSpeed = genesisPoolContract.rewardSpeed();
        uint rewardIndex = genesisPoolContract.rewardIndex();

        if (blockTimestampDelta == 0 || totalSupplies == 0 || rewardSpeed == 0) {
            return rewardIndex;
        }

        uint accrued = rewardSpeed * blockTimestampDelta;
        uint accruedPerCToken = (accrued * 1e36) / totalSupplies;

        return rewardIndex + accruedPerCToken;
    }

    function updateRewardBorrowIndex(
        uint8 rewardType,
        CToken cToken,
        Exp memory marketBorrowIndex
    ) internal view returns (uint224) {
        (uint224 borrowStateIndex, uint32 borrowStateTimestamp) = comptroller.rewardBorrowState(rewardType, address(cToken));
        uint borrowSpeed = comptroller.borrowRewardSpeeds(rewardType, address(cToken));
        uint32 blockTimestamp = uint32(block.timestamp);
        uint deltaTimestamps = sub_(blockTimestamp, uint(borrowStateTimestamp));

        if (deltaTimestamps > 0 && borrowSpeed > 0) {
            uint borrowAmount = div_(cToken.totalBorrows(), marketBorrowIndex);
            uint rewardAccrued = mul_(deltaTimestamps, borrowSpeed);
            Double memory ratio = borrowAmount > 0 ? fraction(rewardAccrued, borrowAmount) : Double({ mantissa: 0 });
            Double memory index = add_(Double({ mantissa: borrowStateIndex }), ratio);

            return uint224(index.mantissa);
        }

        return borrowStateIndex;
    }

    function updateRewardSupplyIndex(
        uint8 rewardType,
        CToken cToken
    ) internal view returns (uint) {
        (uint224 supplyStateIndex, uint32 supplyStateTimestamp) = comptroller.rewardSupplyState(rewardType, address(cToken));
        uint supplySpeed = comptroller.supplyRewardSpeeds(rewardType, address(cToken));
        uint32 blockTimestamp = uint32(block.timestamp);
        uint deltaTimestamps = sub_(blockTimestamp, uint(supplyStateTimestamp));

        if (deltaTimestamps > 0 && supplySpeed > 0) {
            uint supplyTokens = cToken.totalSupply();
            uint rewardAccrued = mul_(deltaTimestamps, supplySpeed);
            Double memory ratio = supplyTokens > 0 ? fraction(rewardAccrued, supplyTokens) : Double({ mantissa: 0 });
            Double memory index = add_(Double({ mantissa: supplyStateIndex }), ratio);

            return index.mantissa;
        }

        return supplyStateIndex;
    }

    function distributeBorrowerReward(
        uint8 rewardType,
        CToken cToken,
        address borrower,
        uint borrowStateIndex,
        Exp memory marketBorrowIndex
    ) internal view returns (uint) {

        Double memory borrowIndex = Double({ mantissa: borrowStateIndex });
        Double memory borrowerIndex = Double({ mantissa: comptroller.rewardBorrowerIndex(rewardType, address(cToken), borrower) });

        if (borrowerIndex.mantissa > 0) {
            Double memory deltaIndex = sub_(borrowIndex, borrowerIndex);
            uint borrowerAmount = div_(cToken.borrowBalanceStored(borrower), marketBorrowIndex);
            uint borrowerDelta = mul_(borrowerAmount, deltaIndex);

            return borrowerDelta;
        }

        return 0;
    }

    function distributeSupplierReward(
        uint8 rewardType,
        CToken cToken,
        address supplier,
        uint supplyStateIndex
    ) internal view returns (uint) {
        Double memory supplyIndex = Double({ mantissa: supplyStateIndex });
        Double memory supplierIndex = Double({ mantissa: comptroller.rewardSupplierIndex(rewardType, address(cToken), supplier) });

        if (supplierIndex.mantissa == 0 && supplyIndex.mantissa > 0) {
            supplierIndex.mantissa = comptroller.initialIndexConstant();
        }

        Double memory deltaIndex = sub_(supplyIndex, supplierIndex);
        uint supplierTokens = cToken.balanceOf(supplier);
        uint supplierDelta = mul_(supplierTokens, deltaIndex);

        return supplierDelta;
    }

    function updateAndDistributeBorrowerReward(
        uint8 rewardType,
        CToken cToken,
        address borrower
    ) internal view returns (uint) {
        Exp memory marketBorrowIndex = Exp({ mantissa: cToken.borrowIndex() });
        uint borrowStateIndex = updateRewardBorrowIndex(rewardType, cToken, marketBorrowIndex);

        return distributeBorrowerReward(rewardType, cToken, borrower, borrowStateIndex, marketBorrowIndex);
    }

    function updateAndDistributeSupplierReward(
        uint8 rewardType,
        CToken cToken,
        address supplier
    ) internal view returns (uint) {
        uint supplyStateIndex = updateRewardSupplyIndex(rewardType, cToken);

        return distributeSupplierReward(rewardType, cToken, supplier, supplyStateIndex);
    }

    function _cTokenBalanceToUnderlying(uint cTokenBalance, CToken market) internal view returns (uint) {
        uint exchangeRate = market.exchangeRateStored();

        return cTokenBalance * exchangeRate / 10 ** 18;
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastValue;
                // Update the index for the moved value
                set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.0;

import "./OwnableUpgradeable.sol";
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2StepUpgradeable is Initializable, OwnableUpgradeable {
    function __Ownable2Step_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable2Step_init_unchained() internal onlyInitializing {
    }
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        require(pendingOwner() == sender, "Ownable2Step: caller is not the new owner");
        _transferOwnership(sender);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

/**
 * @title Exponential module for storing fixed-precision decimals
 * @author RBL
 * @notice Exp is a struct which stores decimals with a fixed precision of 18 decimal places.
 *         Thus, if we wanted to store the 5.1, mantissa would store 5.1e18. That is:
 *         `Exp({mantissa: 5100000000000000000})`.
 */
contract ExponentialNoError {
    uint constant expScale = 1e18;
    uint constant doubleScale = 1e36;
    uint constant halfExpScale = expScale/2;
    uint constant mantissaOne = expScale;

    struct Exp {
        uint mantissa;
    }

    struct Double {
        uint mantissa;
    }

    /**
     * @dev Truncates the given exp to a whole number value.
     *      For example, truncate(Exp{mantissa: 15 * expScale}) = 15
     */
    function truncate(Exp memory exp) pure internal returns (uint) {
        // Note: We are not using careful math here as we're performing a division that cannot fail
        return exp.mantissa / expScale;
    }

    /**
     * @dev Multiply an Exp by a scalar, then truncate to return an unsigned integer.
     */
    function mul_ScalarTruncate(Exp memory a, uint scalar) pure internal returns (uint) {
        Exp memory product = mul_(a, scalar);
        return truncate(product);
    }

    /**
     * @dev Multiply an Exp by a scalar, truncate, then add an to an unsigned integer, returning an unsigned integer.
     */
    function mul_ScalarTruncateAddUInt(Exp memory a, uint scalar, uint addend) pure internal returns (uint) {
        Exp memory product = mul_(a, scalar);
        return add_(truncate(product), addend);
    }

    /**
     * @dev Checks if first Exp is less than second Exp.
     */
    function lessThanExp(Exp memory left, Exp memory right) pure internal returns (bool) {
        return left.mantissa < right.mantissa;
    }

    /**
     * @dev Checks if left Exp <= right Exp.
     */
    function lessThanOrEqualExp(Exp memory left, Exp memory right) pure internal returns (bool) {
        return left.mantissa <= right.mantissa;
    }

    /**
     * @dev Checks if left Exp > right Exp.
     */
    function greaterThanExp(Exp memory left, Exp memory right) pure internal returns (bool) {
        return left.mantissa > right.mantissa;
    }

    /**
     * @dev returns true if Exp is exactly zero
     */
    function isZeroExp(Exp memory value) pure internal returns (bool) {
        return value.mantissa == 0;
    }

    function safe224(uint n, string memory errorMessage) pure internal returns (uint224) {
        require(n < 2**224, errorMessage);
        return uint224(n);
    }

    function safe32(uint n, string memory errorMessage) pure internal returns (uint32) {
        require(n < 2**32, errorMessage);
        return uint32(n);
    }

    function add_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
        return Exp({mantissa: add_(a.mantissa, b.mantissa)});
    }

    function add_(Double memory a, Double memory b) pure internal returns (Double memory) {
        return Double({mantissa: add_(a.mantissa, b.mantissa)});
    }

    function add_(uint a, uint b) pure internal returns (uint) {
        return a + b;
    }

    function sub_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
        return Exp({mantissa: sub_(a.mantissa, b.mantissa)});
    }

    function sub_(Double memory a, Double memory b) pure internal returns (Double memory) {
        return Double({mantissa: sub_(a.mantissa, b.mantissa)});
    }

    function sub_(uint a, uint b) pure internal returns (uint) {
        return a - b;
    }

    function mul_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
        return Exp({mantissa: mul_(a.mantissa, b.mantissa) / expScale});
    }

    function mul_(Exp memory a, uint b) pure internal returns (Exp memory) {
        return Exp({mantissa: mul_(a.mantissa, b)});
    }

    function mul_(uint a, Exp memory b) pure internal returns (uint) {
        return mul_(a, b.mantissa) / expScale;
    }

    function mul_(Double memory a, Double memory b) pure internal returns (Double memory) {
        return Double({mantissa: mul_(a.mantissa, b.mantissa) / doubleScale});
    }

    function mul_(Double memory a, uint b) pure internal returns (Double memory) {
        return Double({mantissa: mul_(a.mantissa, b)});
    }

    function mul_(uint a, Double memory b) pure internal returns (uint) {
        return mul_(a, b.mantissa) / doubleScale;
    }

    function mul_(uint a, uint b) pure internal returns (uint) {
        return a * b;
    }

    function div_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
        return Exp({mantissa: div_(mul_(a.mantissa, expScale), b.mantissa)});
    }

    function div_(Exp memory a, uint b) pure internal returns (Exp memory) {
        return Exp({mantissa: div_(a.mantissa, b)});
    }

    function div_(uint a, Exp memory b) pure internal returns (uint) {
        return div_(mul_(a, expScale), b.mantissa);
    }

    function div_(Double memory a, Double memory b) pure internal returns (Double memory) {
        return Double({mantissa: div_(mul_(a.mantissa, doubleScale), b.mantissa)});
    }

    function div_(Double memory a, uint b) pure internal returns (Double memory) {
        return Double({mantissa: div_(a.mantissa, b)});
    }

    function div_(uint a, Double memory b) pure internal returns (uint) {
        return div_(mul_(a, doubleScale), b.mantissa);
    }

    function div_(uint a, uint b) pure internal returns (uint) {
        return a / b;
    }

    function fraction(uint a, uint b) pure internal returns (Double memory) {
        return Double({mantissa: div_(mul_(a, doubleScale), b)});
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

import "@openzeppelin/contracts-upgradeable/access/Ownable2StepUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import "./CTokenRewardsStorage.sol";

/**
 * @title CToken liquidity incentive rewards 
 * @notice First version of the CTokenRewards contract that receives manual reward allocations for specific users.
 * @dev This contract does no proportional allocation or any other logic to distribute the rewards, it's basically a vault so the users can claim rewards
 */
contract CTokenRewards is Initializable, Ownable2StepUpgradeable, ReentrancyGuardUpgradeable, CTokenRewardsStorageV1 {
  using SafeERC20 for IERC20;
  using EnumerableSet for EnumerableSet.AddressSet;
  
  /// @custom:oz-upgrades-unsafe-allow constructor
  constructor() {
      _disableInitializers();
  }

  /**
   * @notice Standard Initializable method
   */
  function initialize() initializer public {
    __Ownable_init();
    __ReentrancyGuard_init();
  }

  /**
   * Deposits reward tokens allocating different shares to different users
   * @notice The total amount of reward tokens allocated will be transfered from the caller to the contract during this call, 
   *         so make sure to have enough allowance on the reward token for this contract and enough balance.
   *         Also, if the number of users is too big, this function should be called in smaller batches so it does not run out of gas
   * @param rewardToken The token being rewarded to users
   * @param users Users that are being allocated rewards
   * @param amounts Amounts of token reward allocated to the user on the same index
   * @dev The arrays of users and amounts should have the same length
   */
  function depositTokens(address rewardToken, address[] calldata users, uint256[] calldata amounts) external onlyOwner {
    require(users.length > 0 && users.length == amounts.length, "Invalid input");    
    require(rewardToken != address(0), "Invalid reward token");

    uint256 totalAmount;
    IERC20 rewardTokenContract = IERC20(rewardToken);

    uint256 i;
    uint256 userCount = users.length;
    for (; i < userCount;) {
      address user = users[i];
      uint256 amount = amounts[i];

      require(amount > 0, "Amount must be greater than zero");

      userPendingRewards[rewardTokenContract][user] = userPendingRewards[rewardTokenContract][user] + amount;
      totalAmount = totalAmount + amount;
    
      emit TokensDeposited(rewardToken, user, amount);
      unchecked { ++i; }
    }

    rewardTokens.add(rewardToken);
    
    uint balanceBefore = rewardTokenContract.balanceOf(address(this));
    // Transfer tokens from caller to contract
    rewardTokenContract.safeTransferFrom(msg.sender, address(this), totalAmount);
    uint actualTransferredAmount = rewardTokenContract.balanceOf(address(this)) - balanceBefore;

    require(actualTransferredAmount >= totalAmount, "Invalid deposit");
  }

  /**
   * Claims the available rewards for the specified reward token
   * @notice All the available rewards for the token will be claimed to the caller of the function. So only end users should call it
   * @param token The token to claim
   */
  function claimTokens(address token) external nonReentrant {
    require(token != address(0), "Invalid token address");
    IERC20 tokenContract = IERC20(token);
    uint256 amount = userPendingRewards[tokenContract][msg.sender];
    require(amount > 0, "No tokens to claim");

    userPendingRewards[tokenContract][msg.sender] = 0;
    userClaimedRewards[tokenContract][msg.sender] = userClaimedRewards[tokenContract][msg.sender] + amount;
    emit TokensClaimed(msg.sender, token, amount);

    // Transfer tokens to user
    tokenContract.safeTransfer(msg.sender, amount);
  }
  

  /**
   * Deposits ether rewards allocating different shares to different users
   * @notice The total amount of ether allocated will be transfered from the caller to the contract during this call, 
   *         so make sure to have enough ether balance.
   *         Also, if the number of users is too big, this function should be called in smaller batches so it does not run out of gas   
   * @param users Users that are being allocated rewards
   * @param amounts Amounts of ether allocated to the user on the same index
   * @dev The arrays of users and amounts should have the same length
   */
  function depositEther(address[] calldata users, uint256[] calldata amounts) external payable onlyOwner  {
    require(users.length > 0 && users.length == amounts.length, "Invalid input");    

    uint256 totalAmount;
    uint256 i;
    uint256 userCount = users.length;
    for ( ; i < userCount; ) {
      address user = users[i];
      uint256 amount = amounts[i];

      require(amount > 0, "Amount must be greater than zero");

      userPendingEther[user] = userPendingEther[user] + amount;
      totalAmount = totalAmount + amount;
    
      emit EtherDeposited(user, amount);
      unchecked { ++i; }
    }
    
    require(totalAmount == msg.value, "insufficient amount");   
  }
  
  /**
   * Claims the available ether rewards
   * @notice All the available ether be claimed to the caller of the function. So only end users should call it   
   */
  function claimEther() external nonReentrant{
    uint256 amount = userPendingEther[msg.sender];
    require(amount > 0, "No ether to claim");
   
    userPendingEther[msg.sender] = 0;    
    userClaimedEther[msg.sender] = userClaimedEther[msg.sender] + amount;
    emit EtherClaimed(msg.sender, amount);

    // Transfer Ether to user
    (bool success, ) = payable(msg.sender).call{value: amount, gas: 4029}("");    
    require(success, "Transfer failed.");
  }

  /**
   * @dev Checks if an index exists
   */
  modifier validateRewardTokensIndex(uint256 index) {
    require(index < rewardTokens.length(), "validateRewardTokensIndex: index exists?");
    _;
  }

  /**
   * @dev Returns the number of rewards tokens
   */
  function rewardTokensLength() external view returns (uint256) {
    return rewardTokens.length();
  }

  /**
   * @dev Returns rewards token address from given index
   */
  function rewardTokenAt(uint256 index) external view validateRewardTokensIndex(index) returns (address) {
    return address(rewardTokens.at(index));
  }
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;
pragma abicoder v2;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";

/** 
 * First storage model of the CTokenRewards.
 * @dev For future storage changes, new versions should be created and inherit from the previous one
 */
contract CTokenRewardsStorageV1 {
  /// User's pending rewards by reward token address
  mapping(IERC20 => mapping(address => uint256)) public userPendingRewards;
  /// User's claimed rewards by reward token address
  mapping(IERC20 => mapping(address => uint256)) public userClaimedRewards;
  /// User's pending ether rewards
  mapping(address => uint256) public userPendingEther;
  /// User's claimed ether rewards
  mapping(address => uint256) public userClaimedEther;
 
  /// @dev All tokens ever distributed will be present even though no pending rewards are available
  EnumerableSet.AddressSet internal rewardTokens;
  
  /**
   * @notice Event for every new reward allocation
   * @param token the reward token address
   * @param user the user that have been allocated rewards to
   * @param amount the amount of rewards that have been allocated to the user
   */
  event TokensDeposited(address indexed token, address indexed user, uint256 amount);
  /**
   * @notice Event for every an user claims allocated rewards
   * @param user the user that claimed the rewards
   * @param token the reward token address
   * @param amount the amount of reward tokens that have been claimed
   */
  event TokensClaimed(address indexed user, address indexed token, uint256 amount);
  /**
   * @notice Event for every new ether reward allocation   
   * @param user the user that have been allocated rewards to
   * @param amount the amount of rewards that have been allocated to the user
   */
  event EtherDeposited(address indexed user, uint256 amount);
  /**
   * @notice Event for every an user claims allocated ether rewards
   * @param user the user that claimed the rewards   
   * @param amount the amount of ether that have been claimed
   */
  event EtherClaimed(address indexed user, uint256 amount);
}